REPORT ZYNY\_OOALV\_DEMO\_04.  
  
TYPES: BEGIN OF TY\_MATERIAL,  
         MATNR TYPE MATNR,  
         MAKTX TYPE MAKTX,  
       END OF TY\_MATERIAL.  
  
DATA: G\_MATNR     LIKE MARA-MATNR,  
      GT\_MATERIAL TYPE STANDARD TABLE OF TY\_MATERIAL.  
  
\*----------------------------------------------------------------------\*  
\*       CLASS cl\_handler DEFINITION  
\*----------------------------------------------------------------------\*  
\*  
\*----------------------------------------------------------------------\*  
CLASS CL\_HANDLER DEFINITION.  
  PUBLIC SECTION.  
    METHODS ON\_DOUBLE\_CLICK FOR EVENT DOUBLE\_CLICK OF CL\_SALV\_EVENTS\_TABLE  
      IMPORTING ROW COLUMN.  
ENDCLASS.                    "cl\_handler DEFINITION  
  
\*----------------------------------------------------------------------\*  
\*       CLASS cl\_handler IMPLEMENTATION  
\*----------------------------------------------------------------------\*  
\*  
\*----------------------------------------------------------------------\*  
CLASS CL\_HANDLER IMPLEMENTATION.  
  METHOD ON\_DOUBLE\_CLICK.  
    MESSAGE I010(ZNYN\_MESSAGE\_CLASS) WITH ROW COLUMN.  
\*    MESSAGE COLUMN TYPE 'I'.  
    IF COLUMN EQ 'MATNR'.  
      READ TABLE GT\_MATERIAL INTO DATA(WA\_ST\_DATA) INDEX ROW.  
  
\* Check that material exists  
      SELECT COUNT( \* ) FROM MARA UP TO 1 ROWS WHERE MATNR EQ WA\_ST\_DATA-MATNR.  
  
      IF SY-SUBRC = 0. " Exists?  
\* Load parameters  
        SET PARAMETER ID 'MXX' FIELD 'K'. " Default view  
        SET PARAMETER ID 'MAT' FIELD WA\_ST\_DATA-MATNR. " Material number  
\*  
\*        CALL TRANSACTION 'MM03' AND SKIP FIRST SCREEN.  
        CALL TRANSACTION 'MM03'.  
\*        MESSAGE I010(ZNYN\_MESSAGE\_CLASS) WITH WA\_ST\_DATA-MATNR.  
      ELSE. " No ?  
  
        CALL FUNCTION 'CONVERSION\_EXIT\_ALPHA\_OUTPUT'  
          EXPORTING  
            INPUT  = WA\_ST\_DATA-MATNR  
          IMPORTING  
            OUTPUT = WA\_ST\_DATA-MATNR.  
  
        DATA(LV\_ERR) = `Material ` && WA\_ST\_DATA-MATNR && ` does not exist.`.  
        MESSAGE LV\_ERR TYPE 'I' DISPLAY LIKE 'E'.  
      ENDIF.  
    ELSE.  
      MESSAGE TEXT-002 TYPE 'I'. " Invalid cell  
    ENDIF.  
  ENDMETHOD.                    "on\_double\_click  
ENDCLASS.                    "cl\_handler IMPLEMENTATION  
  
SELECTION-SCREEN: BEGIN OF BLOCK B1 WITH FRAME TITLE TEXT-001.  
SELECT-OPTIONS: SO\_MATNR FOR G\_MATNR.  
SELECTION-SCREEN: END OF BLOCK B1.  
  
START-OF-SELECTION.  
  PERFORM RETRIEVE\_DATA.  
  PERFORM DISPLAY.  
  
\*&---------------------------------------------------------------------\*  
\*&      Form  get\_data  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
FORM RETRIEVE\_DATA.  
  SELECT MATNR MAKTX FROM MAKT UP TO 100 ROWS " Retrieve only 100 records  
    INTO TABLE GT\_MATERIAL  
    WHERE MATNR IN SO\_MATNR AND SPRAS EQ SY-LANGU.  
ENDFORM.                    "get\_data  
  
\*&---------------------------------------------------------------------\*  
\*&      Form  display  
\*&---------------------------------------------------------------------\*  
\*       text  
\*----------------------------------------------------------------------\*  
FORM DISPLAY.  
  DATA: LO\_GR\_ALV       TYPE REF TO CL\_SALV\_TABLE, " Variables for ALV properties  
        LO\_GR\_FUNCTIONS TYPE REF TO CL\_SALV\_FUNCTIONS\_LIST.  
  
  DATA: LO\_EVENT\_HANDLER TYPE REF TO CL\_HANDLER, " Variables for events  
        LO\_EVENTS        TYPE REF TO CL\_SALV\_EVENTS\_TABLE.  
  
  DATA: LO\_GRID        TYPE REF TO CL\_SALV\_FORM\_LAYOUT\_GRID, " Variables for header  
        LO\_LAYOUT\_LOGO TYPE REF TO CL\_SALV\_FORM\_LAYOUT\_LOGO,  
        LO\_GRID\_FOOTER        TYPE REF TO CL\_SALV\_FORM\_LAYOUT\_GRID, " Variables for header  
        LO\_LAYOUT\_LOGO\_FOOTER TYPE REF TO CL\_SALV\_FORM\_LAYOUT\_LOGO,  
        LO\_CONTENT     TYPE REF TO CL\_SALV\_FORM\_ELEMENT,  
        LV\_TITLE       TYPE STRING,  
        LV\_FOOTER      TYPE STRING,  
        LV\_ROWS        TYPE STRING.  
  
  DATA: LO\_LAYOUT TYPE REF TO CL\_SALV\_LAYOUT, " Variables for enabling Save button  
        LV\_KEY    TYPE SALV\_S\_LAYOUT\_KEY.  
  
  DATA: LO\_DISPLAY TYPE REF TO CL\_SALV\_DISPLAY\_SETTINGS. " Variable for layout settings  
  
  DATA: LO\_SELECTIONS TYPE REF TO CL\_SALV\_SELECTIONS, " Variables for selection mode and column properties  
        LO\_COLUMNS    TYPE REF TO CL\_SALV\_COLUMNS,  
        LO\_COLUMN     TYPE REF TO CL\_SALV\_COLUMN\_TABLE.  
  
\* Create the ALV object  
  TRY.  
      CALL METHOD CL\_SALV\_TABLE=>FACTORY  
        IMPORTING  
          R\_SALV\_TABLE = LO\_GR\_ALV  
        CHANGING  
          T\_TABLE      = GT\_MATERIAL.  
    CATCH CX\_SALV\_MSG.  
  ENDTRY.  
  
\* Let's show all default buttons of ALV  
  LO\_GR\_FUNCTIONS = LO\_GR\_ALV->GET\_FUNCTIONS( ).  
  LO\_GR\_FUNCTIONS->SET\_ALL( ABAP\_TRUE ).  
  
\* Fit the columns  
  LO\_COLUMNS = LO\_GR\_ALV->GET\_COLUMNS( ).  
  LO\_COLUMNS->SET\_OPTIMIZE( 'X' ).  
  
\* Create header  
  DESCRIBE TABLE GT\_MATERIAL LINES LV\_ROWS.  
  CONCATENATE 'Number of lv\_rows: ' LV\_ROWS INTO LV\_TITLE SEPARATED BY SPACE.  
  
  CREATE OBJECT LO\_GRID.  
  CREATE OBJECT LO\_LAYOUT\_LOGO.  
  LO\_GRID->CREATE\_LABEL( ROW = 1 COLUMN = 1 TEXT = LV\_TITLE TOOLTIP = LV\_TITLE ).  
  LO\_GRID->CREATE\_LABEL( ROW = 2 COLUMN = 2 TEXT = LV\_TITLE TOOLTIP = LV\_TITLE ).  
  LO\_LAYOUT\_LOGO->SET\_LEFT\_CONTENT( LO\_GRID ).  
  LO\_CONTENT = LO\_LAYOUT\_LOGO.  
  LO\_GR\_ALV->SET\_TOP\_OF\_LIST( LO\_CONTENT ).  
  
  CREATE OBJECT LO\_GRID\_FOOTER.  
  CREATE OBJECT LO\_LAYOUT\_LOGO\_FOOTER.  
  LO\_GRID\_FOOTER->CREATE\_LABEL( ROW = 1 COLUMN = 1 TEXT = 'FOOTER TEXT' ).  
  LO\_LAYOUT\_LOGO\_FOOTER->SET\_LEFT\_CONTENT( LO\_GRID\_FOOTER ).  
  LO\_CONTENT = LO\_LAYOUT\_LOGO\_FOOTER.  
  LO\_GR\_ALV->SET\_END\_OF\_LIST( LO\_CONTENT ).  
  
\* Apply zebra style to lv\_rows  
  LO\_DISPLAY = LO\_GR\_ALV->GET\_DISPLAY\_SETTINGS( ).  
  LO\_DISPLAY->SET\_STRIPED\_PATTERN( CL\_SALV\_DISPLAY\_SETTINGS=>TRUE ).  
  
\* Enable the save layout buttons  
  LV\_KEY-REPORT = SY-REPID.  
  LO\_LAYOUT = LO\_GR\_ALV->GET\_LAYOUT( ).  
  LO\_LAYOUT->SET\_KEY( LV\_KEY ).  
  LO\_LAYOUT->SET\_SAVE\_RESTRICTION( IF\_SALV\_C\_LAYOUT=>RESTRICT\_NONE ).  
  LO\_LAYOUT->SET\_DEFAULT( ABAP\_TRUE ).  
  
\* Register events  
  LO\_EVENTS = LO\_GR\_ALV->GET\_EVENT( ).  
  CREATE OBJECT LO\_EVENT\_HANDLER.  
  SET HANDLER LO\_EVENT\_HANDLER->ON\_DOUBLE\_CLICK FOR LO\_EVENTS.  
  
\* Enable cell selection mode  
  LO\_SELECTIONS = LO\_GR\_ALV->GET\_SELECTIONS( ).  
\*  LO\_SELECTIONS->SET\_SELECTION\_MODE( IF\_SALV\_C\_SELECTION\_MODE=>ROW\_COLUMN ).  
  LO\_SELECTIONS->SET\_SELECTION\_MODE( IF\_SALV\_C\_SELECTION\_MODE=>MULTIPLE ).  
  
  TRY.  
      LO\_COLUMN ?= LO\_COLUMNS->GET\_COLUMN( 'MAKTX' ). " Find the 'MAKTX' column ans change attributes  
      LO\_COLUMN->SET\_VISIBLE( IF\_SALV\_C\_BOOL\_SAP=>TRUE ).  
      LO\_COLUMN->SET\_LONG\_TEXT( 'MyTitleLONG' ).  
      LO\_COLUMN->SET\_MEDIUM\_TEXT( 'MyTitleMEDIUM' ).  
      LO\_COLUMN->SET\_SHORT\_TEXT( 'MyTitleS' ).  
    CATCH CX\_SALV\_NOT\_FOUND.  
    CATCH CX\_SALV\_EXISTING.  
    CATCH CX\_SALV\_DATA\_ERROR.  
  ENDTRY.  
  
  LO\_GR\_ALV->DISPLAY( ).  
ENDFORM.                    "display

